Haz una pregunta
  Foros de Electrónica » Diseño digital » Microcontroladores y sistemas embebidos
Foros Registrarse ¿Olvidaste tu contraseña?

Temas similares

15/11/2008 #1


Control de la puerta de un estacionamiento
hola necesito ayuda para la elaboración del control de una puerta de un estacionamiento, estoy trabajando con el pic 16f84, las bases de mi proyecto son las siguientes: debe tener dos finales de carrera, el fc1 y el fc2, un motor que funcione con inversión de giro, y debe estar controlado por un interruptor activado por luz y dos llaves de apertura y cerrado.
mi problema es que ya logre colocar los finales de carrera y ya se realizar la inversión de giro, pero necesito que el motor en algún momento se detenga de manera automática y que no quede girando constantemente hay es donde radica mi duda, si alguien me puede contribuir se lo agradecería mucho. dejare adjunto el archivo que estoy usando.
solo necesito agregarle al circuito el control automatico de los finales de carrera
15/11/2008 #2

Avatar de Moyano Jonathan

aca esta casi concretamente lo que buscas
http://r-luis.xbot.es/descarga/files/Int_Temp.pdf
15/11/2008 #3


ok amigo muchas gracias, acabo de leer la información y esta bastante completa, me pondré a trabajar en ello para culminar el proyecto, te agradezco mucho el aporte, luego de que culmine el proyecto lo colocare
15/11/2008 #4


Realice tal cual las indicaciones que aparecen en el archivo pero el motor no se mueve, no tengo la idea de por que no funciona el circuito
15/11/2008 #5

Avatar de Moyano Jonathan

Revisá bien las conexiones que has realizado, en caso de que te siga sin funcionar veo como despúes te puedo ayudar.
15/11/2008 #6


aca dejo el circuito como le realize junto con el codigo asm, el circuito no corre no varias sus valores a la salida agradezco la ayudas que me puedes brindar para corregirlo
Archivos Adjuntos
Tipo de Archivo: rar proton_138.rar (12,2 KB (Kilobytes), 119 visitas)
15/11/2008 #7

Avatar de Meta

Re: con el control de la puerta de un estacionamiento
hades_21 dijo:
hola necesito ayuda para la elaboración del control de una puerta de un estacionamiento, estoy trabajando con el pic 16f84, las bases de mi proyecto son las siguientes: debe tener dos finales de carrera, el fc1 y el fc2, un motor que funcione con inversión de giro, y debe estar controlado por un interruptor activado por luz y dos llaves de apertura y cerrado.
mi problema es que ya logre colocar los finales de carrera y ya se realizar la inversión de giro, pero necesito que el motor en algún momento se detenga de manera automática y que no quede girando constantemente hay es donde radica mi duda, si alguien me puede contribuir se lo agradecería mucho. dejare adjunto el archivo que estoy usando.
solo necesito agregarle al circuito el control automatico de los finales de carrera
Hola:

Código:
;********************************** Indexado_02.asm *************************************
;
;	===================================================================
;	  Del libro "MICROCONTROLADOR PIC16F84. DESARROLLO DE PROYECTOS"
;	  E. Palacios, F. Remiro y L. López.		www.pic16f84a.com
; 	  Editorial Ra-Ma.  www.ra-ma.es
;	===================================================================
;
; Controla el nivel de un depósito de líquido. Utiliza (entre paréntesis las líneas del
; microcontrolador a la que se han conectado):
; -	Tres sondas detectoras: SV, Sonda de Vacío (RA0); SLL, Sonda de LLenado (RA1);
;	SR, Sonda de Rebose (RA2).
; -	Dos bombas de agua: B1 (RB5), B2 (RB6).
; - Cinco indicadores: Vacio (RB0), Llenandose (RB1), Lleno (RB2), Rebose (RB3),
;	Alarma (RB4).
;
; Su funcionamiento: 
; -	Cuando ninguna de las sondas está mojada se entiende que el depósito está vacío y
;	se accionarán las dos bombas. El indicador "Vacio" se iluminará*.
; -	Cuando el nivel del líquido toque la sonda de vacío "SV" seguirá llenándose el
; 	depósito con las dos bombas. El indicador "Llenandose" se ilumina.
; -	Cuando el nivel del líquido toca la sonda de llenado "SLL", para la bomba B2, quedando
;	B1 activada en modo mantenimiento. El indicador "Lleno" se ilumina.
; -	Si el nivel del líquido moja la sonda de rebose "SR" se apaga también la bomba B1,
;	quedando las dos bombas fuera de servicio. El indicador "Rebose" se enciende.
; -	Cuando se produce un fallo o mal funcionamiento en las sondas de entrada (por
;	ejemplo que se active la sonda de rebose y no active la de vacío) se paran
;	las dos bombas. El indicador "Alarma" se ilumina.
;
; Según el enunciado del problema, teniendo en cuenta las conexiones citadas y poniendo la
; salida no utilizada (RB7) siempre a cero, la tabla de verdad resultante es:
;
; RA2.. RA0 | RB7 ...          ... RB0
; ------------|--------------------------------
;  0   0   0  |  0   1   1   0   0   0   0   1	(Configuración 0. Estado "Vacio").
;  0   0   1  |  0   1   1   0   0   0   1   0	(Configuración 1. Estado "Llenandose").
;  0   1   0  |  0   0   0   1   0   0   0   0	(Configuración 2. Estado "Alarma").
;  0   1   1  |  0   0   1   0   0   1   0   0	(Configuración 3. Estado "Lleno").
;  1   0   0  |  0   0   0   1   0   0   0   0	(Configuración 4. Estado "Alarma").
;  1   0   1  |  0   0   0   1   0   0   0   0	(Configuración 5. Estado "Alarma").
;  1   1   0  |  0   0   0   1   0   0   0   0	(Configuración 6. Estado "Alarma").
;  1   1   1  |  0   0   0   0   1   0   0   0	(Configuración 7. Estado "Rebose").
;
; ZONA DE DATOS **********************************************************************

	LIST		P=16F84A
	INCLUDE		<P16F84A.INC>
	__CONFIG	_CP_OFF &  _WDT_OFF & _PWRTE_ON & _XT_OSC

; ZONA DE CÓDIGOS ********************************************************************

	ORG 	0					; El programa comienza en la dirección 0.
Inicio
	clrf	PORTB				; Debe estar a cero cuando el puerto se configure como salida.
	bsf		STATUS,RP0			; Acceso al Banco 1.
	clrf	TRISB				; Las líneas del Puerto B se configuran como salida.
	movlw	b'00011111'			; Las 5 líneas del Puerto A se configuran como entrada.
	movwf	TRISA
	bcf		STATUS,RP0			; Acceso al Banco 0.
Principal
	movf	PORTA,W				; Lee los sensores.
	andlw	b'00000111'			; Máscara para quedarse con el valor de los sensores.
	addwf	PCL,F				; Salta a la configuración adecuada.
	goto	Configuracion0
	goto	Configuracion1
	goto	Configuracion2
	goto	Configuracion3
	goto	Configuracion4
	goto	Configuracion5
	goto	Configuracion6
	goto	Configuracion7
Configuracion0
	movlw 	b'01100001'			; Estado "Vacio" (configuración 0).
	goto	ActivaSalida
Configuracion1
	movlw 	b'01100010'			; Estado "Llenándose" (configuración 1).
	goto	ActivaSalida
Configuracion2
	movlw 	b'00010000'			; Estado "Alarma" (configuración 2).
	goto	ActivaSalida
Configuracion3
	movlw 	b'00100100'			; Estado "Lleno" (configuración 3).
	goto	ActivaSalida
Configuracion4
	movlw 	b'00010000'			; Estado "Alarma" (configuración 4).
	goto	ActivaSalida
Configuracion5
	movlw 	b'00010000'			; Estado "Alarma" (configuración 5).
	goto	ActivaSalida
Configuracion6
	movlw 	b'00010000'			; Estado "Alarma" (configuración 6).
	goto	ActivaSalida
Configuracion7
	movlw 	b'00001000'			; Estado "Rebose" (configuración 7).
ActivaSalida
	movwf	PORTB				; Visualiza por el puerto de salida.
	goto 	Principal

	END
	
;	===================================================================
;	  Del libro "MICROCONTROLADOR PIC16F84. DESARROLLO DE PROYECTOS"
;	  E. Palacios, F. Remiro y L. López.		www.pic16f84a.com
; 	  Editorial Ra-Ma.  www.ra-ma.es
;	===================================================================
Saludos.
16/11/2008 #8


ok amigo muchas gracias lo he puesto en practcia y me ha ayudado a resolver una parte del problema
Respuesta
¿Tienes una mejor respuesta a este tema? ¿Quieres hacerle una pregunta a nuestra comunidad y sus expertos? Registrate

Foros de Electrónica » Diseño digital » Microcontroladores y sistemas embebidos

Powered by vBulletin® Version 3.8.4
Copyright ©2000 - 2017, Jelsoft Enterprises Ltd.
Search Engine Optimization by vBSEO ©2011, Crawlability, Inc.