Haz una pregunta
  Foros de Electrónica » Diseño digital » Microcontroladores y sistemas embebidos
Foros Registrarse ¿Olvidaste tu contraseña?

Temas similares

26/02/2012 #21

Avatar de Meta

Hola:

R3 y R4 están ahó por como dices. Se relacionan con los pulsadores R5 y R6 ya que el código como expliqué arriba.

en el mismo puerto funciona como interruptor, cambia de estado se comporta como comunicación al LCD y así sucesivamente a una velocidad pasmosa.
Los puntos rojos significan que está el positivo en ese momento, también conocido como 1. Los azules como 0 o como negativo o masa.

Lso grises significa que están desconectados, no se usan o si se usan que pueden ser apagado o encendido en ese momento. También se desactivan solos ni encendido ni apagado, sobre todo la parte LCD.

Un slaudo.
26/02/2012 #22


a no ser, que sean pulsadores normalmente cerrados!

No he leido el programa, pero he hechado un vistazo a mi libro, y usa puertas totalmente distintas.....tb lleva el programa temporizador....

Tengo ke contraatacarle al pic

---------- Actualizado después de 2 minutos ----------

kritter dijo: Ver Mensaje

No he leido el programa, pero he hechado un vistazo a mi libro...

Porque tu link esta en hex no en asm, no por desprecio, jejejejje.


Pero vamos ke seran el mismo pero con puertas distintas
27/02/2012 #23

Avatar de Meta

Hola:

¿Lo lees?

Código:
;********************************** INT_Temporizador.asm ********************************
;
;    ===================================================================
;      Del libro "MICROCONTROLADOR PIC16F84. DESARROLLO DE PROYECTOS"
;      E. Palacios, F. Remiro y L. López.            www.pic16f84a.com
;       Editorial Ra-Ma.  www.ra-ma.es
;    ===================================================================
;
; Programa de control para un temporizador digital de precisión. La programación del tiempo
; de temporización se realiza mediante dos pulsadores: "AJUSTE" y "ON/INCREM". Funcionamiento:
;     -    En estado de reposo la salida del temporizador está apagada y el pantalla aparece el
;        tiempo deseado para la próxima temporización.
;     - Si se pulsa "ON/INCREM" comienza la temporización.
;     - Cuando acaba la temporización pasa otra vez a reposo.
;     -    Si pulsa "AJUSTE" antes que haya acabado el tiempo de temporización actúa como pulsador
;        de paro: interrumpe la temporización, apaga la carga y pasa al estado de reposo.
;
; Para ajustar la temporización al tiempo deseado. 
;     -    Pulsa "AJUSTE" y ajusta el tiempo deseado mediante el pulsador "ON/INCREM".
;     -    Se vuelve a pulsar "AJUSTE" y pasa a modo de reposo.
;
; Al apagar el sistema debe conservar el tiempo de temporización deseado para la próxima vez
; que se encienda.
;
; ZONA DE DATOS **********************************************************************

    LIST        P=16F84A
    INCLUDE        <P16F84A.INC>
    __CONFIG    _CP_OFF &  _WDT_OFF & _PWRTE_ON & _XT_OSC

    CBLOCK  0x0C
    TiempoDeseado                ; El tiempo deseado de temporización.
    Tiempo                        ; Tiempo que resta de temporización.
    FlagsModos                    ; Guarda los flags con los diferentes
    ENDC                        ; modos de funcionamiento.

    ORG    0x2100                    ; Corresponde a la dirección 0 de la zona
                                ; EEPROM de datos. Aquí se va a guardar el
    DE    0x00                    ; tiempo de temporización deseado.

#DEFINE  F_Temporizador_ON        FlagsModos,2
#DEFINE  F_Temporizador_Ajuste    FlagsModos,1
#DEFINE  F_Temporizador_OFF        FlagsModos,0

#DEFINE  SalidaTemporizador     PORTB,1        ; Salida donde se conecta la carga.
#DEFINE  Zumbador                 PORTB,2        ; Salida donde se conecta el zumbador.
#DEFINE  AjustePulsador            PORTB,7        ; Los pulsadores están conectados a estas
#DEFINE  IncrementarPulsador    PORTB,6        ; líneas del Puerto B.

; ZONA DE CÓDIGOS ********************************************************************

    ORG     0
    goto    Inicio
    ORG    4
    goto    ServicioInterrupcion

Mensajes
    addwf    PCL,F
Mensaje_ON
    DT "   En MARCHA", 0x00
Mensaje_Ajuste
    DT "Tiempo  deseado:", 0x00
Mensaje_OFF
    DT "     PARADO", 0x00

; Instrucciones de inicialización. ------------------------------------------------------
;
Inicio
    call    LCD_Inicializa
    bsf        STATUS,RP0
    movlw    b'10000111'                    ; Prescaler de 256 asignado al TMR0.
    movwf    OPTION_REG
    bsf        AjustePulsador                ; Configurados como entradas.
    bsf        IncrementarPulsador
    bcf        SalidaTemporizador            ; Configurados como salidas.
    bcf        Zumbador
    bcf        STATUS,RP0
    clrw                                ; Lee la posición 0x00 de memoria EEPROM de datos
    call    EEPROM_LeeDato                ; donde se guarda el tiempo deseado de la última vez
    movwf    TiempoDeseado                ; que se ajustó.
    call    ModoTemporizador_OFF        ; Modo de funcionamiento inicial.
    movlw    b'10001000'                    ; Activa interrupciones RBI.
    movwf    INTCON
Principal
    goto    Principal

; Subrutina "ServicioInterrupcion" ------------------------------------------------------
;
; Detecta qué ha producido la interrupción y ejecuta la subrutina de atención correspondiente.

ServicioInterrupcion
    btfsc    INTCON,T0IF
    call    Temporizador
    btfss    INTCON,RBIF                    ; Si es una interrupción RBI lee los pulsadores.
    goto    FinInterrupcion
    btfss    AjustePulsador                ; ¿Está presionado el pulsador de "AJUSTE"?.
    call    CambiarModo                    ; Sí, pues salta a la subrutina correspondiente.
    btfsc    IncrementarPulsador            ; ¿Pulsado "ON/INCREM"?.
    goto    FinInterrupcion                ; No, pues salta al final y sale.
;
    call    Retardo_20ms                ; Espera que se estabilice el nivel de tensión.
    btfsc    IncrementarPulsador            ; Si es un rebote del pulsador "ON/INCREM" sale fuera.
    goto    FinInterrupcion
    btfsc    F_Temporizador_OFF            ; ¿Estaba en reposo cuando pulsó "ON/INCREM"?
    call    ModoTemporizador_ON            ; Sí, pues comienza la temporización.
    btfsc    F_Temporizador_Ajuste        ; ¿Estaba ajustando tiempo?
    call    IncrementarTiempoDeseado    ; Sí, pues pasa a incrementar el tiempo deseado.
FinInterrupcion
    bcf        INTCON,RBIF                    ; Limpia los flags de reconocimiento.
    bcf        INTCON,T0IF
    retfie

; Subrutinas "CambiarModo" y todas las de MODO de funcionamiento ------------------------
;
; Subrutina de atención a la interrupción producida al presionar el pulsador "AJUSTE" que 
; cambia el modo de funcionamiento.

; Hay identificados tres modos de funcionamiento que se diferencian mediante los tres flags:
;    A)    Modo "Temporizador_OFF" o estado inicial. A él se pasa en el estado inicial cada vez
;        que termina una temporización o cuando se aborta la temporización sin esperar a que
;        finalice. Reconocido por el flag F_Temporizador_OFF, bit 0 del registro FlagsModos.
;         una temporización  o cada vez que se aborta la temporización sin esperar a que finalice.
;    B)    Modo "Temporizador_Ajuste", donde se ajusta la temporización deseada cuando funcione
;        como temporizador. Reconocido por el flag F_Temporizador_Ajuste, bit 1 del FlagsModos.
;    C)    Modo "Temporizador_ON", la salida está activada mientras dure la temporización.
;        Reconocido por el flag F_Temporización_ON, que es el bit 2 del registro FlagsModos.
;
; El programa consigue que esté activado uno sólo de los flags anteriores.

; El contenido del registro (FlagsModos) diferencia los siguientes modos de funcionamiento:
; - (FlagsModos)=b'00000001'. Está en el modo "Temporizador_OFF", en reposo.
; - (FlagsModos)=b'00000010'. Está en el modo "Temporizador_Ajuste", ajustando tiempo deseado.
; - (FlagsModos)=b'00000100'. Está en el modo "Temporizador_ON", activa la carga y temporizador.
;
; Al pulsar "AJUSTE" pueden darse tres casos:
; - Si estaba en modo "Temporizador_OFF", pasa a modo "Temporizador_Ajuste".
; - Si estaba en modo "Temporizador_Ajuste", pasa a modo "Temporizador_OFF", pero antes salva
;   el tiempo de temporización deseado en la EEPROM de datos.       
; - Si estaba en modo "Temporizador_ON", pasa a modo "Temporizador_OFF". (Interrumpe la
;   temporización).

CambiarModo
    call    PitidoCorto                    ; Cada vez que pulsa origina un pitido. 
    btfsc    AjustePulsador                ; Si es un rebote sale fuera.
    goto    EsperaDejePulsar
    btfsc    F_Temporizador_OFF            ; ¿Está en reposo?
    goto    ModoTemporizador_Ajuste        ; Sí, pues pasa a ajustar la temporización.
    btfss    F_Temporizador_Ajuste        ; ¿Está ajustando?
    goto    ModoTemporizador_OFF        ; No, pues pasa a reposo.
                                        ; Sí, pues antes de pasar a reposo salva en la
    clrw                                ; posición 00h de memoria EEPROM de datos el tiempo 
    movwf    EEADR                        ; de temporización deseado. Se conserva aunque se
    movf    TiempoDeseado,W                ; apague la alimentación.
    call    EEPROM_EscribeDato
ModoTemporizador_OFF
    bcf        SalidaTemporizador            ; Apaga la carga y resetea tiempo deseado.
    call    Pitido
    movlw    b'00000001'                ; Actualiza el registro FlagsModos pasando al
    movwf    FlagsModos                ; modo inicial "Temporizador_OFF".
    bcf        INTCON,T0IE                ; Prohíbe las interrupciones del TMR0.
    movf    TiempoDeseado,W            ; Repone otra vez el tiempo que se desea para la 
    movwf    Tiempo                    ; próxima temporización.
    call    LCD_Borra                ; Borra la pantalla.
    movlw    Mensaje_OFF                ; En pantalla el mensaje correspondiente.
    goto    FinCambiarModo

ModoTemporizador_Ajuste
    bcf        SalidaTemporizador        ; Apaga la carga
    movlw    b'00000010'                ; Actualiza el registro FlagsModos pasando al
    movwf    FlagsModos                ; modo "Temporizador_Ajuste".
    clrf    Tiempo                    ; Resetea el tiempo.
    clrf    TiempoDeseado
    bcf        INTCON,T0IE                ; Prohíbe las interrupciones del TMR0.
    call    LCD_Borra
    movlw    Mensaje_Ajuste            ; En pantalla el mensaje correspondiente.
    goto    FinCambiarModo

ModoTemporizador_ON
    movf    TiempoDeseado,W            ; Si el tiempo deseado es cero pasa a modo
    btfsc    STATUS,Z                ; de trabajo "Temporizador_OFF".
    goto    ModoTemporizador_OFF
    movwf    Tiempo
    call    PitidoCorto
    movlw    b'00000100'                ; Actualiza el registro FlagsModos pasando al
    movwf    FlagsModos                ; modo "Temporizador_ON".
    movlw    TMR0_Carga50ms            ; Carga el TMR0.
    movwf    TMR0
    movlw    CARGA_1s                ; Y el registro cuyo decremento contará los
    movwf    Registro50ms            ; segundos.
    bsf        INTCON,T0IE                ; Autoriza las interrupciones de TMR0.
    call    LCD_Borra
    bsf        SalidaTemporizador        ; Enciende la carga.
    movlw    Mensaje_ON                ; En pantalla el mensaje correspondiente.
FinCambiarModo
    call    LCD_Mensaje
    call    VisualizaTiempo
EsperaDejePulsar
    btfss    AjustePulsador            ; Espera deje de pulsar.
    goto    EsperaDejePulsar
    return

; Subrutina "Temporizador" ----------------------------------------------------------------
;
; Esta subrutina va decrementando el tiempo de temporización y visualizándolo en la pantalla.
; Se ejecuta debido a la petición de interrupción del Timer 0 cada 50 ms exactos, comprobado
; experimentalmente con la ventana "Stopwatch" del simulador del MPLAB.

    CBLOCK
    Registro50ms                    ; Guarda los incrementos cada 50 ms.
    ENDC

TMR0_Carga50ms    EQU    d'256'-d'195'            ; Para conseguir la interrupción cada 50 ms.
CARGA_1s        EQU    d'20'            ; Leerá cada segundo (20 x 50ms = 1000 ms).    

Temporizador
    call    Retardo_50micros        ; Ajuste fino de 71 microsegundos para
    call    Retardo_20micros        ; ajustar a 50 milisegundos exactos.
    nop
      movlw    TMR0_Carga50ms            ; Carga el Timer0.
    movwf    TMR0
    decfsz    Registro50ms,F            ; Decrementa el contador.
    goto    FinTemporizador            ; No ha pasado 1 segundo y por tanto sale.
    movlw    CARGA_1s                ; Repone el contador nuevamente.
    movwf    Registro50ms
    btfss    F_Temporizador_ON        ; Si no está en modo "Temporizador_ON" sale
    goto    FinTemporizador            ; fuera.
    decfsz    Tiempo,F
    goto    VisualizaContador        ; Visualiza el tiempo restante.
    bcf        SalidaTemporizador        ; Apaga la salida
    call    VisualizaTiempo            ; Visualiza cero segundos en la pantalla.
    call    Pitido                    ; Tres pitidos indican final de la temporización.
    call    Retardo_500ms
    call    Pitido
    call    Retardo_500ms
    call    PitidoLargo
    call    Retardo_500ms
    call    ModoTemporizador_OFF    ; Acabó la temporización.
    goto    FinTemporizador
VisualizaContador
    call    VisualizaTiempo
FinTemporizador
    return

; Subrutina "VisualizaTiempo" -----------------------------------------------------------------
;
; Visualiza el registro Tiempo en formato "Minutos:Segundos". Así por ejemplo, si
; (Tiempo)=124 segundos en la segunda línea de la pantalla visualiza " 2:04", ya que 124
; segundos es igual a 2 minutos más 4 segundos.
;
VisualizaTiempo
    movlw    .5                        ; Para centrar visualización en la
    call    LCD_PosicionLinea2        ; segunda línea.
    movf    Tiempo,W                ; Convierte el tiempo deseado (y expresado sólo en
    call    MinutosSegundos            ; segundos) a minutos y segundos.
    movf    TemporizadorMinutos,W    ; Visualiza los minutos.
    call    BIN_a_BCD                ; Lo pasa a BCD.
    call    LCD_Byte
    movlw    ':'                        ; Visualiza dos puntos.
    call    LCD_Caracter
    movf    TemporizadorSegundos,W    ; Visualiza los segundos.
    call    BIN_a_BCD                ; Lo pasa a BCD.
    goto    LCD_ByteCompleto
    return

; Subrutina "MinutosSegundos" -----------------------------------------------------------
;
; Una cantidad expresada exclusivamente en segundos y contenida en el registro W es
; convertida a minutos y segundos. El resultado se guarda en dos posiciones de memoria
; llamadas TemporizadorMinutos y TemporizadorSegundos.
;
; El máximo número a convertir será el 255 que es el máximo valor que puede adquirir el
; número binario de entrada de 8 bits. (255 segundos = 4 minutos + 15 segundos)
;
; El procedimiento utilizado es mediante restas de 60 tal como se explica en el siguiente
; ejemplo que trata de la conversión del 124 segundos a minutos y segundos.
; 124 segundos = 2 minutos + 4 segundos. 
;
; Minutos        Segundos     ¿(Segundos)<60?
; -------        --------    ------------------------------------------------
;     0              124        NO. Resta 60 a (Segundos) e incrementa (Minutos).
;     1               64         NO. Resta 60 e (Segundos) e incrementa (Minutos).
;     2                4        Sí, se acabó. 
;
; Entrada:    En el registro W el número de segundos a convertir.
; Salidas:    En (TemporizadorMinutos) y (TemporizadorSegundos) el resultado.

    CBLOCK
    TemporizadorMinutos
    TemporizadorSegundos
    ENDC
;
MinutosSegundos
    movwf    TemporizadorSegundos    ; Carga el número de segundos a convertir.
    clrf    TemporizadorMinutos        ; Carga los registros con el resultado inicial.
Resta60
    movlw    .60                        ; Resta 60 en cada pasada.
    subwf    TemporizadorSegundos,W    ; (W)=(TemporizadorSegundos)-60.
    btfss    STATUS,C                ; ¿(W) positivo?, ¿(TemporizadorSegundos)>=60?.
    goto     FinMinutosSegundos        ; No, es menor de 60. Acabó.
    movwf    TemporizadorSegundos    ; Sí, por tanto, recupera lo que queda por restar.
    incf    TemporizadorMinutos,F    ; Incrementa los minutos.
    goto    Resta60                    ; Y vuelve a dar otra pasada.
FinMinutosSegundos
    return

; Subrutina "IncrementarTiempoDeseado" --------------------------------------------------
;
; Subrutina de atención a la interrupción por cambio de la línea RB6 a la cual se ha
; conectado el pulsador "INCREMENTAR".
; Estando en el modo "Temporizador_Ajustar" incrementa el valor del tiempo deseado
; expresado en segundos en intervalos de 5 segundos y hasta un máximo de 255 segundos.
;
SALTO_INCR    EQU    .5

IncrementarTiempoDeseado
    call    PitidoCorto                ; Cada vez que pulsa se oye un pitido.
    movlw    SALTO_INCR                ; Incrementa el tiempo deseado de temporización
    addwf    Tiempo,F                ; saltos de SALTO_INCR segundos.
    btfsc    STATUS,C                ; Si pasa del valor máximo lo inicializa.
    clrf    Tiempo
    call    VisualizaTiempo            ; Visualiza mientras espera que deje de pulsar.
    call    Retardo_200ms
    btfss    IncrementarPulsador        ; Mientras permanezca pulsado,
    goto    IncrementarTiempoDeseado ; incrementa el dígito.
    movf    Tiempo,W                ; Actualiza el tiempo deseado.
    movwf    TiempoDeseado            ; Este es el tiempo deseado.
    return
    
; Subrutinas "PitidoLargo", "Pitido" y "PitidoCorto" -------------------------------------
;
PitidoLargo
    bsf        Zumbador
    call    Retardo_500ms
Pitido
    bsf        Zumbador
    call    Retardo_200ms
PitidoCorto
    bsf        Zumbador
    call    Retardo_20ms
    bcf        Zumbador
    return
;
    INCLUDE  <RETARDOS.INC>
    INCLUDE  <BIN_BCD.INC>
    INCLUDE  <LCD_4BIT.INC>
    INCLUDE  <LCD_MENS.INC>
    INCLUDE  <EEPROM.INC>
    END

;    ===================================================================
;      Del libro "MICROCONTROLADOR PIC16F84. DESARROLLO DE PROYECTOS"
;      E. Palacios, F. Remiro y L. López.        www.pic16f84a.com
;       Editorial Ra-Ma.  www.ra-ma.es
;    ===================================================================
Un cordial saludo.
27/02/2012 #24


espero no haber molestado
Disculpa meta,
siento haberte hinchado a preguntas, ojalá algun dia pueda yo contestarlas y aportar respuestas en este foro, de momento estoy en el inicio de mi desarrollo.

Gracias por el code voy a revisarlo pero de momento mi problema persiste. poniendo el codigo hex tal cual cuando enchufo se me ve la pantalla negra, la linea superior.

desconozco si los pulsadores tienen que ser normalmente cerrados o normalmente abiertos, he probado puenteando los abiertos para ver si cambiaba su comportamiento y no pasa nada.

el zumbador si que funciona cuando hago pulsaciones pero nunca puedo activar la carga(como tampoco veo nada en la pantalla...)

la pantalla la he conectado correctamente, los dos primeros pines son 15 y 16, no se conectan, los siguientes 6 si se conectan para:
1-gnd
2-5V
3-anclado al variable de un pot de 10k para regular el brillo
En realidad las tres las conecto con el pot, masa, vdd y ajuste de brillo


4>>A pin 17 PIC RA0
5.gnd
6 >>pin 1 del PIC RA2


7,8,9,10 no se conectan

11>>RB4 pin 10 del pic
12>> RB5 pin 11 del pic
13>> RB6 pin 12 del pic
14>>RB7 pin 13 del pic

En el pic:
1 RA2 se conecta a 6 de LCD
2 RA3 no se conecta
3 RA4/TOCKI no se conecta
4 MCLR conectado a dos resistencias(100ohm y pulsador en serie y10K y VDD en serie)
5GND
6RB0/int no se conecta
7RB1 a CARGA(relé 12 V)
8RB2 a zumbador 6V
9RB3 no se conecta( no voy a poner altavoz, lo he probado en board y da mucho ruido)
10RB4 pin 11 LCD
11RB5 pin 12 LCD
12RB6 pin13 LCD/R de 10K y VDD serie/R de 330 y pulsador serie
13RB7 pin14 LCD/R de 10K y VDD serie/R de 330 y pulsador serie
14 a VDD
15 a Xtal 4MHZ(con su cap de 22micros
15 a Xtal 4MHZ
17 RA0 a pin 4 LCD
18 RA1 no se conecta


Lo he comprobado todo y revisado, cortos etc. no entiendo que puede estar pasando, porke en principio el fallo parece solo en el lcd, porque sin querer he activado la carga desde uno de los pulsadores(no se como) y ha estado durante unos segundos y luego ha hecho 3 zumbidos como alarma de paro, por lo que creo que el programa esta correcto.

Aunque en mi humilde opinion de novato que ignora muchos conocimientos, pienso que puede que el problema esté en el refresco de la imagen, solo asi entenderia que se viese toda la linea en negro, lo se porque estuve intentando montar la insoladora con este proyecto:

http://www.turbokeu.com/myprojects/countdown3.htm

tenia ese problema de refresco con los displays por una metida de gamba mia con los transistores, luego el propio autor aclaraba que los mandos de los pulsadores, funcionaban raro debido a los tiempos de espera,

Si quieres te envio al mail una captura de mi esquematico y del pcb.(privado)

Muchas Gracias por tu atencion.

Salud!!!
27/02/2012 #25

Avatar de Meta

Hola de nuevo:

El programa está bien. Efectivamente, son tres pitidos al acabar de contar. El LCD cámbialo por otro por probar, quizás no lo tengas bien. La pantalla como aparece la primera línea todo negro y abajo nada, significa que no está configurado, es como si lo conectaras sin PIC.



Pulsadores son normalmente abierto.

Un saludo.
28/02/2012 #26


Justo estaba pensando lo de la pantalla, pero tambien he pensado en si he quemado el pic...

aunque el zumbador zumba cuando aprieto los botones...no se como comprobarlo, intentaré usar uno que sepa que funciona ademas de la pantalla....

Gracias por la ayuda
14/03/2012 #27


uaka
Bueno Meta,

Al final me llegaron unas pantallas LCD de Futurlec ....(tiene buenos precios pero si pueden te encaloman cosas sin pedirlo, y por supuesto te las cobran, ademas del inconveniente de la aduana que me ha tenido esperando semana y media)...y bueno, era justo y simplemente eso, la pantalla LCD esta petada, no lo he probado en tu esquema, hice uno nuevo a partir de la edición antigua del libro, que solo cuenta con dos botones, es decir, no tiene el reset, omite algunas resistencias y tiene las puertas asignadas de otra forma. Pero es lo mismo, lo he probado en Board y funcionaba con las nuevas LCD.

Luego he probado ahi la pantalla vieja y seguia igual, solo saca la barra negra de arriba, como si no le llegara info del PIC.

Ademas, los PIC que usaba antes apenas se les lee las letras que tienen escritas indicando su modelo, lo cual me hace sospechar ke tuvo algun rekalentón y perecieron....

Debo de añadir que en el libro viejo el programa en .asm no se compila bien por algun motivo, incluso desde un cd original ocurre esto, aunque su version compilada en .hex si que es funcional. Subiré el esquemático en cuanto pueda.

Ahora, solo me queda decidir la forma de alimentarlo, si con trafo externo o trafo interno, porque ya tengo la placa de la fase de alimentación y relé de 12V pero ocupan mucho espacio y me gustaría minimizarlo....

...me imagino que habrá alguna forma de evitar poner relé con otro PIC u otro programa.

De todas formas, GRACIAS POR TODO EL SOPORTE Y APOYO, ahora me voy 3 meses a Polonia y veré si alli pruebo con tu esquema, aunque lo veo complicado, no tengo programador....mi eclipse se ha escacharrao....
15/03/2012 #28

Avatar de Meta

Hola:

El LCD puedes comprarlo por Bilbao y lo traen si problemas.

LCD verde

LCD azul

¿Qué te han puesto que no has pedido y encima te cobran?

Es bueno hacerlo notificar a ellos que no estás de acuerdo con el trato, con el tiempo se lo pensarán mejor si la gente hace estar reclamaciones.

El esquema funciona bien, me funciona y hasta lo probaré con PIC16F84A, subiré un vídeo para que te guedes tranquilo.

Que tengas buen viaje en Polonia.

PD: Con el tiempo, en algún momento encerrado en una casa ta aburrirás y te meterás por Internet, puedes que pases por aquí desde Polonia. Es bueno que tengas el grabador de PIC como el TE20x o el TE20-SE por menos de 20€, funciona a la primera.
17/03/2012 #29

Avatar de Meta

Hola de nuevo.

Me pasaba lo mismo que a ti, volví a montarlo desde cero y con tranquilidad.

En este ejemplo ya es un módulo montado.



Más adelante te monto el que hice el temporizador de prueba en la protoboard.
24/06/2012 #30

Avatar de jhorevil

Meta dijo: Ver Mensaje
Hola:

¿Lo lees?

Un cordial saludo.
soy nuevo en esto de la programacion...quiciera me pudieran ayudar e tratado de copilar este ejercicio en el mplab pero me da muchos errores me dice que no encuentra unas librerias o al asi.

---------- Actualizado después de 5 minutos ----------

estos son los errores:
Código:
Clean: Deleting intermediary and output files.
Clean: Done.
Executing: "C:\Program Files (x86)\Microchip\MPASM Suite\MPAsmWin.exe" /q /p16F84A "INT_Temporizador.asm" /l"INT_Temporizador.lst" /e"INT_Temporizador.err"
Warning[215] C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 27 : Processor superseded by command line.  Verify processor symbol.
Message[301] C:\PROGRAM FILES (X86)\MICROCHIP\MPASM SUITE\P16F88.INC 40 : MESSAGE: (Processor-header file mismatch.  Verify selected processor.)
Error[108]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 29 : Illegal character (,)
Error[108]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 30 : Illegal character (,)
Error[118]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 30 : Overwriting previous address contents (2007)
Error[118]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 30 : Overwriting previous address contents (2007)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 79 : Symbol not previously defined (LCD_Inicializa)
Message[302] C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 82 : Register in operand not in bank 0.  Ensure that bank bits are correct.
Message[302] C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 84 : Register in operand not in bank 0.  Ensure that bank bits are correct.
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 92 : Symbol not previously defined (EEPROM_LeeDato)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 95 : Symbol not previously defined (EEPROM_LeeDato)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 117 : Symbol not previously defined (Retardo_20ms)
Message[302] C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 168 : Register in operand not in bank 0.  Ensure that bank bits are correct.
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 170 : Symbol not previously defined (EEPROM_EscribeDato)
Message[302] C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 171 : Register in operand not in bank 0.  Ensure that bank bits are correct.
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 173 : Symbol not previously defined (EEPROM_EscribeDato)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 184 : Symbol not previously defined (LCD_Borra)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 197 : Symbol not previously defined (LCD_Borra)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 221 : Symbol not previously defined (LCD_Borra)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 225 : Symbol not previously defined (LCD_Mensaje)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 246 : Symbol not previously defined (Retardo_50micros)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 247 : Symbol not previously defined (Retardo_20micros)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 272 : Symbol not previously defined (Retardo_500ms)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 274 : Symbol not previously defined (Retardo_500ms)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 276 : Symbol not previously defined (Retardo_500ms)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 292 : Symbol not previously defined (LCD_PosicionLinea2)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 299 : Symbol not previously defined (BIN_a_BCD)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 300 : Symbol not previously defined (LCD_Byte)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 302 : Symbol not previously defined (LCD_Caracter)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 304 : Symbol not previously defined (BIN_a_BCD)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 305 : Symbol not previously defined (LCD_ByteCompleto)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 357 : Symbol not previously defined (Retardo_200ms)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 370 : Symbol not previously defined (Retardo_500ms)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 373 : Symbol not previously defined (Retardo_200ms)
Error[113]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 376 : Symbol not previously defined (Retardo_20ms)
Error[105]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 380 : Cannot open file (Include File "RETARDOS.INC" not found)
Error[105]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 381 : Cannot open file (Include File "BIN_BCD.INC" not found)
Error[105]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 382 : Cannot open file (Include File "LCD_4BIT.INC" not found)
Error[105]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 383 : Cannot open file (Include File "LCD_MENS.INC" not found)
Error[105]   C:\PIC\16F84A\INT_TEMPORIZADOR.ASM 384 : Cannot open file (Include File "EEPROM.INC" not found)
Halting build on first failure as requested.
BUILD FAILED: Sun Jun 24 00:50:41 2012
24/06/2012 #31

Avatar de Meta

Porque faltan las librerías que no incluí.
INCLUDE <RETARDOS.INC> INCLUDE <BIN_BCD.INC> INCLUDE <LCD_4BIT.INC> INCLUDE <LCD_MENS.INC> INCLUDE <EEPROM.INC>
28/06/2012 #32

Avatar de jhorevil

Meta dijo: Ver Mensaje
Porque faltan las librerías que no incluí.
INCLUDE <RETARDOS.INC> INCLUDE <BIN_BCD.INC> INCLUDE <LCD_4BIT.INC> INCLUDE <LCD_MENS.INC> INCLUDE <EEPROM.INC>
gracias Meta: ya encontré las librerías,me podrías decir como cambiar los minutos solo me cuenta hasta 4:15 (minutos/seg) y vuelve a cero quisiera aumentarle el rango en donde podría modificar eso.
28/06/2012 #33

Avatar de Meta

Ahora mismo no puedo porque no lo tengo en este PC, si no en otro y no puedo acceder hasta que compre una conmutada nueva.

Lo he logrado hasta los 99:99.

Saludo.
28/06/2012 #34

Avatar de jhorevil

Meta dijo: Ver Mensaje
Ahora mismo no puedo porque no lo tengo en este PC, si no en otro y no puedo acceder hasta que compre una conmutada nueva.

Lo he logrado hasta los 99:99.

Saludo.
uy te agradecería me colaboraras con eso, es muy urgente para mi, tengo que poner a contabilizar unos equipos pero necesito que se apaguen en cierto tiempo...meta agradeceria mucho tu apoyo.
29/06/2012 #35

Avatar de Meta

Colaborar en eso significa ir a comprar una conmutada, buscar donde lo tengo, comprobarlo y más cosas que ahora no estoy en la labor. Se que en este foro lo he subido, lo que no recuerdo el tema.
29/06/2012 #36

Avatar de jhorevil

Meta dijo: Ver Mensaje
Colaborar en eso significa ir a comprar una conmutada, buscar donde lo tengo, comprobarlo y más cosas que ahora no estoy en la labor. Se que en este foro lo he subido, lo que no recuerdo el tema.
bueno de todas maneras muchas gracias.
18/07/2014 #37


No puedo generar el hex temporizador, ayuda...
Hola mikeekim, quisiera saber por que no puedo generar el archivo hex del temporizador, que es lo que estoy haciendo mal, adjunto la imagen con los errores de antemano gracias...
Imágenes Adjuntas
Tipo de Archivo: jpg pbp.jpg (107,5 KB (Kilobytes), 12 visitas)
18/07/2014 #38
Moderador

Avatar de D@rkbytes

El último mensaje de mkeekim fue el 31/03/2012 y tal vez no te responda.

Pero para poder compilar el programa del post#1, elimina o comenta las primeras 8 definiciones dejando únicamente las definiciones desde DEFINE OSC 4 en adelante.

En vez de las definiciones eliminadas, agrega esta palabra de configuración:
@ Device XT_OSC, PWRT_ON, BOD_OFF, LVP_OFF

Con eso ya lo debes poder compilar.

Suerte.
19/07/2014 #39


Logre ensamblarlo...
Gracias por responder D@rkbytes, se ve que mikeekim no ingresa hace mucho...quería aprovechar para decirte si has armado alguna vez este temporizador en el protoboard, porque mikeekim se queja en el armado no le funcionaba; pero en la simulación si trabaja correctamente.

Espero me des una respuesta pronto, ya que eres de gran ayuda; siempre solucionando problemas...
19/07/2014 #40
Moderador

Avatar de D@rkbytes

alex26 dijo: Ver Mensaje
Gracias por responder D@rkbytes, se ve que mikeekim no ingresa hace mucho...quería aprovechar para decirte si has armado alguna vez este temporizador en el protoboard, porque mikeekim se queja en el armado no le funcionaba; pero en la simulación si trabaja correctamente.

Espero me des una respuesta pronto, ya que eres de gran ayuda; siempre solucionando problemas...
Nop, la verdad nunca he armado ese proyecto, pero viendo el esquema, no se ve complicado.
Móntalo sobre un protoboard para que hagas pruebas de su funcionamiento.
¿Tienes una mejor respuesta a este tema? ¿Quieres hacerle una pregunta a nuestra comunidad y sus expertos? Registrate

Foros de Electrónica » Diseño digital » Microcontroladores y sistemas embebidos

Powered by vBulletin® Version 3.8.4
Copyright ©2000 - 2017, Jelsoft Enterprises Ltd.
Search Engine Optimization by vBSEO ©2011, Crawlability, Inc.